greda.f

c this is <greda.f>
c------------------------------------------------------------------------------
c $Id: greda.f,v 1.23 2010-03-10 17:31:35 tforb Exp $
c
c 24/06/97 by Thomas Forbriger (IfG Stuttgart)
c
c evaluate greens function for a set of seismograms
c
c ----
c This program is free software; you can redistribute it and/or modify
c it under the terms of the GNU General Public License as published by
c the Free Software Foundation; either version 2 of the License, or
c (at your option) any later version. 
c 
c This program is distributed in the hope that it will be useful,
c but WITHOUT ANY WARRANTY; without even the implied warranty of
c MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
c GNU General Public License for more details.
c 
c You should have received a copy of the GNU General Public License
c along with this program; if not, write to the Free Software
c Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA  02110-1301  USA
c ----
c
c REVISIONS and CHANGES
c    24/06/97   V1.0   Thomas Forbriger
c    03/07/97   V1.1   included hankel functions
c    08/07/97   V1.2   correct 1/2 factors for hankel functions
c    25/07/97   V1.3   calculate Fourier Bessel transform
c                      first slowness to be calculated is larger than zero
c                      included distance taper
c                      included special handling for u=zero
c    04/08/97   V1.4   now optional matrix inversion method
c                      and correct linear inversion
c    07/08/97   V1.5   build a correct algorithm using wielandt gauss
c    08/08/97   V2.0   reorganized the whole thing
c                      added edge setting
c    14/08/97   V2.1   added direct matrix method
c                      added K_0 damping method
c                      added discrete gram method
c    22/10/97   Vx.x   special version using imsl
c                      change matrix routine and L-rho
c    23/10/97   V2.2   - use double precision (real) matrix methods
c                      - introduced a workspace common block
c    29/10/97   V2.3   - introduced definition for damping factor
c                        relativ to omega, r_max and s_max
c    30/10/97   V2.4   - all methods should be correct now
c    31/10/97   V2.5   - now with gaussian distance taper
c                      - and gaussian time domain taper
c    06/11/97   V2.6   - starting work on Henry, Orcutt Parker method
c                      - fix problem with frequency=zero
c    12/01/98   V2.7   - fix use of minr (to be able to more than
c                        on receiver at the same offset)
c                      - rearrange help and add some more help
c                      - new option -Q
c                      - stacking of seismograms with same offset
c                      - allow different numbers of samples
c    14/01/98   V2.8   - be more verbose when stacking
c    08/06/98   V3.0   - added the plane wave stacking algorithm
c                        new major version as option naming changed
c    12/08/98   V3.1   - ok there was false information in the help text...
c                        it was a misuse of -P option
c    18/08/98   V3.2   - correct stacking algorithm 
c                        did refer to r(i) and not to r(i)/n
c    28/02/99   V3.3   - allow negative slowness values when stacking plane
c                        waves
c                      - changed order of if,elseif,.. section setting
c                        planewaves to the front
c    02/03/99   V3.4   - there was a servere bug in the spectra calculation
c                        routine - the transform array was not initialized
c                        correctly
c    13/05/99   V3.5   - allow scaling of individual spectral coefficients
c    20/04/00   V3.6   - there was an error in trace sorting in subroutine
c                        parker which should have lead to wrong results with
c                        non-sorted offset data
c                      - and gram(ntr,ntr) was zero
c    27/04/00   V3.7   - report HOP expansion numbers
c                      - scale Fourier Bessel transform with HOP factors
c    29/04/00   V3.8   - hooo - there was still an error in the HOP gram
c                        inverse expansion to alpha
c    24/05/00   V3.9   - changed cosine distance taper to apply factor greater
c                        than zero to last trace
c    21/06/00   V3.10  the trapezoid rule in subroutine backcoeff was awfully
c                      misbehaved
c    23/06/00   V3.11  trapezoid rule was still wrong by a constant factor 2
c    12/06/02   V3.12  two years later :-)
c                      Introduce a "number of wavelength" taper (option -W).
c                      This functionality is implemented into the subroutines
c                      planestack for the Slant Stack algorithm and into
c                      subroutine expmodel. In expmodel it makes only sense
c                      together with the Bessel transform, since only in that
c                      case the inverse of the Gram matrix is diagonal.
c    13/09/02   V3.13  - add extra offset taper
c                      - output seismogram spectra
c    16/09/02   V3.14  - write phasor walkout to file
c    28/03/06   V3.15  - apply special (offset dependent taper) after
c                        rescaling waveforms
c                      - corrected subroutine specialtap
c    27/11/09   V3.16  - some corrections to satify gfortran
c               V3.17  - pwo_init takes an argument!
c    10/03/10   V3.18  - correction in taper function: second index of array
c                        spectra is sample index
c
c==============================================================================
c
      program greda
c
c first we declare some general variables
c
      character*79 version,CVSID
      parameter(version='GREDA   V3.18   Greens function from data')
      parameter(CVSID=
     &  '$Id: greda.f,v 1.23 2010-03-10 17:31:35 tforb Exp $')
c
c calculations common block
      include 'greda_dim.inc'
      include 'greda.inc'
c any
      integer i,j
      real pi2
      parameter(pi2=2.*3.141592653589793)
c 
c----------------------------------------------------------------------
c here follows everything we need for the input data hold
c
c datafile
      character*80 filename, Fourierfile
      real fdata(maxsamp)
      integer idata(maxsamp)
      equivalence(fdata, idata)
      real r(maxtr), dt, tfirst, maxr, minr
c receiver chain
      integer chain(maxtr), firstrec
c 
c----------------------------------------------------------------------
c here is everything we need to perform the calculations
c
c inner product damping exponents
      real rho, rhoq, sigma, expon
c 
c----------------------------------------------------------------------
c here follows what we need to hold and write the output data
c
c magic number for binary file identification
      integer magic
      character*4 cmagic
      parameter(cmagic='1234')
c magic number for trace spectra binary file identification
      integer spmagic
      character*4 cspmagic
      parameter(cspmagic='SP34')
c greens function
      character*80 greensfile
      complex green(maxslo, maxom)
      real slo(maxslo), om(maxom), omq
      real smax, fmax
c file
      integer lu
      parameter(lu=20)
c 
c selected method
      character*70 method
      character*2 kernel
c 
c----------------------------------------------------------------------
c here we go with command line parameters
c
c parameters
      real tapfrac, offtapfrac, edgefrac, minoff, stackdelta, rescaleexpo
      real hopnumberfrequency, wltaplen, wltapfrac
      real tapoffsets(4)
      real pwofreq, pwoslo
      character*(80) pwofilename, pwffilename, pwafilename
      logical hopnumberthis, backtranscale
      logical debug, overwrite, hankel1, hankel2, verbose, uzerospecial
      logical matrixmethod, lininv, offtaper, edgeset, linkinv
      logical disgram, softcosine, gausstaper, gausstime, parkermethod
      logical stackso, planewave, rescale, specrescale, hopnumbers
      logical applywltaper,specialtaper,writeFourier
      logical pwofile, pwoautofile, pwosel
c command line
      integer maxopt, lastarg, iargc
      parameter(maxopt=35)
      character*4 optid(maxopt)
      character*80 optarg(maxopt)
      logical optset(maxopt), opthasarg(maxopt)
c here are the keys to our commandline options
      data optid/2h-d,2h-t,2h-s,2h-n,2h-f,2h-o,2h-1,2h-2,2h-v,2h-T,2h-S,
     &  2h-M,2h-L,2h-q,2h-E,2h-K,2h-D,2h-a,2h-b,2h-g,2h-H,2h-O,2h-Q,2h-B,
     &  2h-P,2h-r,2h-F,2h-N,2h-X,2h-W,4h-tap,4h-spo,3h-pw,4h-pwf,4h-pwa/
      data opthasarg/.FALSE.,4*.TRUE.,4*.FALSE.,.TRUE.,3*.FALSE.,2*.TRUE.,
     &  6*.FALSE.,2*.TRUE.,.TRUE.,.FALSE.,.TRUE.,.FALSE.,.TRUE.,.FALSE.,
     &  6*.TRUE./
      data optarg/1h-,3h10.,2h8.,1h5,4h100.,4*1h-,2h0.,3*1h-,5h1.,1.,
     &  2h1.,6*1h-,4h0.01,5h1.,1.,4*1h-,3h10.,1h-,6h1.,10.,
     &  11h0.,0.,0.,0.,4*3hnil/
c 
c======================================================================
c 
c go on with executable code
c
      print *,version
      print *,'Usage: greda datafile greensfile'
      print *,'             [-L] [-K] [-P] [-D] [-M] [-H]'
      print *,'             [-n nslo] [-s smax] [-f fmax]'
      print *,'             [-t frac] [-T frac] [-E edge]'
      print *,'             [-W n,f] [-a] [-b] [-g]'
      print *,'             [-O minoff] [-B delta] [-r expo] [-F]'
      print *,'             [-1] [-2] [-q f,e] [-Q f,e] [-S]'
      print *,'             [-v] [-o] [-N f] [-X]'
      print *,'             [-tap o1,o2,o3,o4]'
      print *,'             [-spo filename]'
      print *,'             [-pw f,p,file]'
      print *,'             [-pwf filename]'
      print *,'             [-pwa filename]'
      print *,'or     greda -help'
c 
      if (iargc().lt.1) stop 'ERROR: missing parameters'
      call getarg(1, filename)
      if (filename(1:5).eq.'-help') then
        print *,' '
        print *,'Calculate Green''s Function from a set of seismograms'
        print *,'by using linear inversion theory. Actually does'
        print *,'a Fourier-Bessel transform by default.'
        print *,' '
        print *,CVSID
        print *,'Copyright 1997 by Thomas Forbriger'
        print *,' '
        print *,'datafile     Name of file containing seismograms.'
        print *,'             The program will expect a homogeneous dataset.'
        print *,'             This means a dataset where all traces have'
        print *,'             the same time of first sample and the same'
        print *,'             sampling interval.'
        print *,'greensfile   Name of file to contain results.'
        print *,' '
        print *,'Available alternatives to the Fourier-Bessel transform:'
        print *,'-L           Calculate by linear inversion (exp-damping).'
        print *,'-K           Calculate by linear inversion (K_0-damping).'
        print *,'-H           Use the method following Henry, Orcutt and Parker:'
        print *,'             Calculate by linear inversion (Lorentz-damping).'
        print *,'             This uses a special integral formula that'
        print *,'             leads to a direct matrix inversion.'
        print *,'             The theory is given in:'
        print *,'               Henry, M., Orcutt, J.A., Parker, R.L., 1980,'
        print *,'               A new method for slant stacking refraction data'
        print *,'               Geoph. Res. Lett., vol. 7, 1073-1076'
        print *,'-D           Calculate by linear inversion (gram matrix'
        print *,'             calculated by discrete numerical integration).'
        print *,'-M           Calculate Green''s matrix by simple matrix'
        print *,'             inversion. (This is a DIRTY way - please don''t'
        print *,'             take it!)'
        print *,'-P           Assume that data represents plane waves. Solve'
        print *,'             by ordinary stacking method (well known as'
        print *,'             ''slant stack'').'
        print *,' '
        print *,'How to define the range in the green:'
        print *,'-n nslo      Number of slowness to be scanned from'
        print *,'             greens function. (default is number of'
        print *,'             seismic traces read)'
        print *,'-s smax      Maximum slowness value for scanning the'
        print *,'             greens function in s/km. (default is ',
     &          optarg(3)(1:4),')'
        print *,'-f fmax      Maximum frequency value in Hz. (default'
        print *,'             is to take all theoretical frequencies)'
        print *,' '
        print *,'How to apply tapers to the input data:'
        print *,'-t tfrac     Tapering fraction for each end of the time'
        print *,'             series in percent. (default is ',
     &          optarg(2)(1:4),')'
        print *,'             In the case of a gaussian taper this value gives'
        print *,'             the amplitude fraction of the edge samples'
        print *,'             compared to it''s original values.'
        print *,'-T ofrac     Tapering (cosine taper) fraction for the far end'
        print *,'             of the profile in percent.'
        print *,'             In the case of a gaussian taper this value gives'
        print *,'             the amplitude fraction of the last trace'
        print *,'             compared to it''s original value.'
        print *,'             The default is not to apply any offset domain'
        print *,'             taper.'
        print *,'-tap o1,o2,o3,o4'
        print *,'             special offset taper'
        print *,'             the taper is 0. for offsets smaller than'
        print *,'               o1 and offsets larger than o4'
        print *,'             the taper i 1. for offsets between o2'
        print *,'               and o3'
        print *,'             it has a sine edge between o1 and'
        print *,'               and o2 and a cosine edge between o3'
        print *,'               and o4'
        print *,'-E edge      Specify the sample from which on all'
        print *,'             samples should be tapered to zero as a'
        print *,'             fraction of the time series length.'
        print *,'             (2.*tfrac <= edge <= 1.)'
        print *,'-a           Apply smooth cosine distance taper ',
     &            '(default is hard).'
        print *,'-b           Apply gaussian distance taper ',
     &            '(default is hard cosine).'
        print *,'-g           Apply gaussian time domain taper ',
     &            '(default is cosine).'
        print *,'-W n,f       Apply an offset domain cosine taper of'
        print *,'             exactly ''n'' wavelengths length, where'
        print *,'             ''n'' may be a floating point value.'
        print *,'             The taper fraction (falling edge) is'
        print *,'             given by ''f'' in percent of the taper'
        print *,'             length. The taper length depends then on'
        print *,'             frequency and slowness.'
        print *,'             This option applies to only to the Slant'
        print *,'             Stack and the Bessel transformation.'
        print *,'             In terms of slowness resolution ''n'' '
        print *,'             defines it to be'
        print *,'             delta p = p / n.'
        print *,'-O minoff    Set minimum offset difference that will be'
        print *,'             used to find the minimum receiver distance.'
        print *,'             That is usefull in cases where multiple'
        print *,'             receivers occur at the same offset position.'
        print *,'             (default is ',
     &          optarg(22)(1:4),')'
        print *,'-B delta     Stack all traces lying within the same offset'
        print *,'             interval delta. We will take the mean offset'
        print *,'             value for the stacked result.'
        print *,'-r expo      Rescale seismograms to energy damping of'
        print *,'             r^(-expo) with r being the offset. For'
        print *,'             surface waves without dissipation expo should'
        print *,'             be one.'
        print *,'-F           Do rescaling in the frequency domain to energy'
        print *,'             damping of (omega*r)^(-expo). In this'
        print *,'             case every single Fourier coefficient will'
        print *,'             be rescaled for itself. This procedure will'
        print *,'             just leave the phase information. No amplitude'
        print *,'             information will be conserved.'
        print *,' '
        print *,'Parameters controlling expansion of Green''s Function:'
        print *,'-1           Use the hankel function H^(1)_0 instead of J_0'
        print *,'-2           Use the hankel function H^(2)_0 instead of J_0'
        print *,'-q f,e       Damping factor for inner product.'
        print *,'             The inner product damping will be calculated'
        print *,'             as rho=delta_r_min*f*omega**e.'
        print *,'             default is: ',optarg(14)(1:8)
        print *,'-Q f,e       Damping factor for inner product.'
        print *,'             The inner product damping will be calculated'
        print *,'             as rho=f*omega**e. Overrides settings of'
        print *,'             -q option.'
        print *,'             proposed: ',optarg(23)(1:8)
        print *,'-S           Special handling of zero slowness. This option'
        print *,'             is useful together with the hankel functions'
        print *,'             which become singular at argument zero.'
        print *,'             To calculate the greens coefficients at'
        print *,'             slowness zero we use the Bessel function.'
        print *,'-X           scale Fourier Bessel transform with HOP factors'
        print *,'             (crazy option!)'
        print *,' '
        print *,'Phasor walkout:'
        print *,'-pw f,p,file write phasor walkout for frequency f and'
        print *,'             slowness p to file'
        print *,'-pwf file    read phasor walkout selection from file'
        print *,'             each line has three entries:'
        print *,'             frequency, slowness, filename'
        print *,'-pwa file    read phasor walkout selection from file'
        print *,'             but generate output filenames automatic'
        print *,'             each line has two entries:'
        print *,'             frequency, slowness'
        print *,' '
        print *,'Other parameters:'
        print *,'-o           Overwrite existing output file.'
        print *,'-v           Be somehow verbose.'
        print *,'-N f         print HOP numbers for frequency f'
        print *,'-spo filename'
        print *,'             write seismic traces'' Fourier'
        print *,'             coefficients to file ''filename'' '
        print *,' '
        print *,'How it works:'
        print *,'In cases -L, -K, -H and -D (linear inversion) we use'
        print *,'a scalar product of the type'
        print *,' '
        print *,'  (f,g) = int_0^P f(p) g(p) D(p) p dp.'
        print *,' '
        print *,'J_0(p*omega*r_j) is called the representer of the data'
        print *,'value d_j, which here is the Fourier expansion coefficient'
        print *,'for the vartical displacement at frequency omega and'
        print *,'offset r_j.'
        print *,' '
        print *,'In case -D P is equal to the maximum slowness and D(p)=1.'
        print *,'In the other cases P is infinity and D(p) is given by'
        print *,' '
        print *,'  D(p) = exp(-rho^2*p^2),         (case -L)'
        print *,'  D(p) = K_0(rho*p), and          (case -K)'
        print *,'  D(p) = 1/(p^2+1/rho^2).         (case -H)'
        print *,' '
        print *,'rho should be chosen somewhere around delta_r_min*omega,'
        print *,'where delta_r_min is the minimal offset difference.'
        print *,' '
        print *,'$Id: greda.f,v 1.23 2010-03-10 17:31:35 tforb Exp $'
        call pwo_cvsid
        print *,' '
        print *,'compiled array dimensions are:'
        print *,'      samples: ',maxsamp
        print *,'       traces: ',maxtr
        print *,'   slownesses: ',maxslo
        print *,'  frequencies: ',maxom
        print *,' '
        print *,'magic numbers:'
        print *,'  Green coefficient files: ',cmagic
        print *,'  Trace coefficient files: ',cspmagic
        stop
      endif
c 
c
c----------------------------------------------------------------------
c 
c configure from command line
c 
c      print *,'DEBUG: call iargc'
      if (iargc().lt.2) stop 'ERROR: missing parameters'
c      print *,'DEBUG: call tf_cmdline'
      call tf_cmdline(3, lastarg,
     &     maxopt, optid, optarg, optset, opthasarg)
c      print *,'DEBUG: returned from tf_cmdline'
      call getarg(1, filename)
      call getarg(2, greensfile)
      debug=optset(1)
      if (debug) print *,'DEBUG: in options - place 1'
      read(optarg(2), *, err=99) tapfrac
      if (tapfrac.gt.50.) stop 'ERROR: silly taper'
      if (tapfrac.lt.0.) stop 'ERROR: negative taper'
      read(optarg(3), *, err=99) smax
      smax=smax*0.001
      read(optarg(4), '(i10)', err=99) nslo
      if (nslo.lt.1) stop 'ERROR: need positive number of slownesses'
      if (nslo.gt.maxslo) stop 'ERROR: too many slownesses'
      read(optarg(5), *, err=99) fmax
      if (fmax.lt.0.) stop 'ERROR: negative maximum frequency'
      overwrite=optset(6)
      if (debug) print *,'DEBUG: in options - place 2'
      hankel1=optset(7)
      hankel2=optset(8)
      verbose=optset(9)
      offtaper=optset(10)
      if (offtaper) then
        read(optarg(10), *, err=99) offtapfrac
        if (offtapfrac.gt.50.) stop 'ERROR: silly taper'
        if (offtapfrac.lt.0.) stop 'ERROR: negative taper'
      endif
      if (debug) print *,'DEBUG: in options - place 3'
      uzerospecial=optset(11)
      matrixmethod=optset(12)
      lininv=optset(13)
      read (optarg(14), *) sigma,expon
      edgeset=optset(15)
      if (edgeset) then
        read(optarg(15), *, err=99) edgefrac
        if (edgefrac.gt.1.) stop 'ERROR: end of taper behind last sample'
        if (edgefrac.lt.(0.02*tapfrac)) 
     &    stop 'ERROR: edge does not leave enough space for taper'
      endif
      if (debug) print *,'DEBUG: in options - place 4'
      linkinv=optset(16)
      disgram=optset(17)
      softcosine=optset(18)
      gausstaper=optset(19)
      gausstime=optset(20)
      parkermethod=optset(21)
      read (optarg(22), *) minoff
      if ((.not.optset(14)).and.(optset(23)))
     &  read (optarg(23), *) sigma,expon
      stackso=optset(24)
      if (stackso) read (optarg(24), *) stackdelta
      planewave=optset(25)
      rescale=optset(26)
      if (debug) print *,'DEBUG: in options - place 5'
      specrescale=optset(27)
      if (rescale) then
        read(optarg(26), *) rescaleexpo
        if (specrescale) rescale=.false.
      else
        specrescale=.false.
      endif
      hopnumbers=optset(28)
      read(optarg(28), *) hopnumberfrequency
      backtranscale=optset(29)
      applywltaper=optset(30)
      read(optarg(30), *) wltaplen, wltapfrac
      if (debug) print *,'DEBUG: in options - place 6'
      specialtaper=optset(31)
      if (specialtaper) read(optarg(31), *) (tapoffsets(i), i=1,4)
      writeFourier=optset(32)
      Fourierfile=optarg(32)
      pwosel=optset(33)
      if (pwosel) read(optarg(33), *) pwofreq, pwoslo, pwofilename
      pwofile=optset(34)
      pwffilename=optarg(34)
      pwoautofile=optset(35)
      pwafilename=optarg(35)
      if (debug) print *,'DEBUG: read options'
c 
      if ((.not.(planewave)).and.(smax.lt.0.))
     &  stop 'ERROR: negative maximum slowness'

c----------------------------------------------------------------------
c initialize common block for phasor walkout
c      print *,'DEBUG: call pwo_init'
      call pwo_init(verbose)
c      print *,'DEBUG: returned from pwo_init'
c----------------------------------------------------------------------
c report
      print *,' '
      if (hankel1) then
        print *,'I will use the hankel function H^(1)_0 of order zero'
        kernel='H1'
      elseif (hankel2) then
        print *,'I will use the hankel function H^(2)_0 of order zero'
        kernel='H2'
      else
        print *,'I will use the Bessel function of the first kind J_0',
     &    ' of order zero'
        kernel='J'
      endif
      print *,' '
c 
c initialize wavelength taper factors
      if (debug) print *,'DEBUG: call initwltaper(wltaplen,wltapfrac)'
      call initwltaper(wltaplen,wltapfrac)
c
c----------------------------------------------------------------------
c phasor walkout selection
c
      if (pwosel) 
     &  call pwo_selpair(pwofreq*pi2,pwoslo,pwofilename,verbose)
      if (pwofile) call pwo_readsel(pwffilename, .false., verbose)
      if (pwoautofile) call pwo_readsel(pwafilename, .true., verbose)
c 
c----------------------------------------------------------------------
c 
c go for the real calculations
c 
c read seismic data
      if (debug) print *,'DEBUG: call readdata'
      call readdata(filename, fdata, idata, spectra, r, maxr,
     &     maxtr, maxsamp, ntr, nsamp, dt, tfirst)
      if (debug) print *,'DEBUG: returned from readdata'
c 
      if ((.not.optset(4)).or.(matrixmethod)) nslo=ntr
      if (nslo.gt.maxslo) stop 'ERROR: too many slownesses - check code'
c 
c do stacking
      if (stackso) call stackthem(r, stackdelta, maxr, verbose)
c
c get distances in increasing order
      call tf_rchain(r, chain, ntr, firstrec, 1)
c
c find minimum distance step
      j=firstrec
      i=chain(j)
      minr=maxr
      do while (i.gt.0)
        if (abs(r(i)-r(j)).gt.minoff) minr=min(minr,abs(r(i)-r(j)))
        j=i
        i=chain(i)
      enddo
      print *,' '
      print *,' minimum distance between receivers: ',minr
      print *,'maximum source to receiver distance: ',maxr
c 
      if ((.not.optset(14)).and.(optset(23)))
     &  sigma=sigma/minr
c 
      print *,'rho=',minr*sigma,'*omega**',expon
c 
c apply tapers
      call taper(maxsamp, maxtr, ntr, nsamp, tapfrac, offtapfrac,
     &  maxr, spectra, r, offtaper, verbose, edgeset, edgefrac,
     &  softcosine, gausstaper, gausstime)
c 
c rescale traces if we want them to be rescaled
      if (rescale) call dorescale(rescaleexpo, r)
c
c apply special tapers
      if (specialtaper) 
     &  call specialtap(maxsamp, maxtr, ntr, nsamp, tapoffsets, maxr,
     &    spectra, r, verbose)
c 
c calculate complex spectra
      call calcspec(dt, tfirst, om,
     &  fmax, optset(5))
c
c write Fourier coefficients
      if (writeFourier) 
     &  call Fourierwrite(Fourierfile, spmagic, cspmagic, overwrite,
     &    r, maxr, om)
c 
c rescale traces if we want them to be rescaled
      if (specrescale) call dospecrescale(rescaleexpo, r, om)
c 
c set slowness range
      call setslo(maxslo, nslo, smax, slo, 
     &  hankel1, hankel2, uzerospecial)
c 
c----------------------------------------------------------------------
c 
c now calculate the greens matrix
c handle each frequency individually
c
      hopnumberthis=.false.
      do i=1,nom
c 
c init phasor walkout
        call pwo_initable(om,slo,nom,nslo,i,verbose)
c 
c damping
c
c something usefull
        omq=om(i)*om(i)
        rho=minr*sigma*om(i)**expon
        rhoq=rho*rho
c 
c do we hopnumber? ;-)
        if (hopnumbers) then
          hopnumberthis=.false.
c          print *,abs(hopnumberfrequency-om(i)/pi2)
c          print *,(0.55*(om(2)-om(1))/pi2)
          if (abs(hopnumberfrequency-om(i)/pi2).lt.(0.501*(om(2)-om(1))/pi2)) 
     &    then
            hopnumberthis=.true.
            print *,' '
            print *,'HOP numbers request for ',
     &              hopnumberfrequency,' Hz comes at ',om(i)/pi2,' Hz'
            print *,'rho is ',rho
          endif
        endif
c
c algorithm section
c =================
c
c Provided algorithms are:
c
c   1. Slant Stack (assuming plane waves)
c   2. HOP-method (linear inversion with Lorentz-damping)
c   3. linear inversion with exp-damping
c   4. linear inversion with K_0-damping
c   5. linear inversion with boxcar damping
c   6. the dirty direct matrix inversion
c   7. discrete Fourier-Bessel transformation
c
c The following conditionals select one of the provided algorithms.
c The standard sequence of calculations is:
c
c   1. calculate a Gram matrix
c      (subroutines gramex, gramket, gramdis)
c   2. calculate expansion coefficients alpha from Gram matrix
c      by numerical solution of system of linear equations
c      (subroutine modexp) 
c   3. calculate model vector of linear inversion from
c      coefficients alpha and selected representer
c      (subroutine expmodel)
c   4. scale model to Green matrix coefficients
c      (subroutines scalpark, scalex, scalkmet)
c
c Deviations from this scheme:
c
c   - the boxcar damping does not need scaling (step 4)
c   - the Bessel transformation combines steps 1 and two in subroutine
c     backcoeff and does not need scaling (step 4)
c   - the HOP-method knows the inverse of the Gram matrix and omits step 2
c   - the slant stack is too easy to use more than one subroutine ;-)
c     (subroutine planestack)
c   - the dirty direct inversion sets up its one system of linear equations
c     (subroutine forwardmat) and uses subroutine modexp to solve it
c     (steps 3 and 4 are not necessary)
c 
        if (planewave) then
c 
c 1. Slant Stack (assuming plane waves)
c calculate stacking algorithm with plane wave assumption
c -------------------------------------------------------
          if (i.eq.1) then
            print *,' '
            print *,'assume plane waves and use stacking algorithm...'
            print *,' '
            method='Slant Stack'
          endif
          call planestack(om(i), slo, r, green, i, applywltaper)
c 
        elseif (parkermethod) then
c 
c 2. HOP-method (linear inversion with Lorentz-damping)
c calculate by Henry Orcutt Parker integral
c -----------------------------------------
          if (i.eq.1) then
            print *,' '
            print *,'use gram matrix given by Henry, Orcutt and Parker'
            print *,' '
            method='HOP-inversion with '//kernel//' kernel'
            call nullmodel(green)
          else
            if (verbose) then
              print *,'f=',om(i)/pi2,'   rho=',rho
            endif
            rho=om(i)/rho
            rhoq=omq/rhoq
            call parker(rho, r, spectra(1, i), chain, firstrec, hopnumberthis)
            call expmodel(om(i), r, slo, green(1, i),
     &        hankel1, hankel2, uzerospecial, .false.)
            call scalpark(nslo, rhoq, omq, green(1, i), slo,
     &        hopnumberthis,ntr)
          endif
c 
        elseif (lininv) then
c 
c 3. linear inversion with exp-damping
c calculate by linear inversion exponential damping
c -------------------------------------------------
          if (i.eq.1) then
            print *,' '
            print *,'do it by linear inversion (exponential damping)'
            print *,' '
            method='inversion with exp-damping and '//kernel//' kernel'
            call nullmodel(green)
          else
            if (verbose) then
              print *,'f=',om(i)/pi2,'   rho=',rho
            endif
            call gramex(rhoq, omq, r)
            call modexp(i, spectra(1, i))
            call expmodel(om(i), r, slo, green(1, i),
     &        hankel1, hankel2, uzerospecial, .false.)
            call scalex(nslo, rhoq, green(1, i), slo, ntr)
          endif
c 
        elseif (linkinv) then
c 
c 4. linear inversion with K_0-damping
c calculate by linear inversion K_0 damping
c -----------------------------------------
          if (i.eq.1) then
            print *,' '
            print *,'do it by linear inversion (K_0-damping)'
            print *,' '
            method='inversion with K0-damping and '//kernel//' kernel'
            call nullmodel(green)
          else
            if (verbose) then
              print *,'f=',om(i)/pi2,'   rho=',rho
            endif
            call gramkmet(rhoq, omq, r)
            call modexp(i, spectra(1, i))
            call expmodel(om(i), r, slo, green(1, i),
     &        hankel1, hankel2, uzerospecial, .false.)
            call scalkmet(nslo, rho, green(1, i), slo, ntr)
          endif
c 
        elseif (disgram) then
c 
c 5. linear inversion with boxcar damping
c calculate by linear inversion with discrete gram
c ------------------------------------------------
          if (i.eq.1) then
            print *,' '
            print *,'do it by linear inversion (discrete gram)'
            print *,' '
          endif
          if (verbose) then
            print *,'going for frequency ',i,' of ',nom
          endif
          call gramdis(slo, om(i), r)
          call modexp(i, spectra(1, i))
          call expmodel(om(i), r, slo, green(1, i), 
     &      hankel1, hankel2, uzerospecial, .false.)
c 
        elseif (matrixmethod) then
c 
c 6. the dirty direct matrix inversion
c calculate green matrix by matrix inversion method
c -------------------------------------------------
          if (i.eq.1) then
            print *,' '
            print *,'do it by direct matrix inversion'
            print *,' '
            print *,'THIS IS A DIRTY WAY! You will run into trouble...'
            method='dirty direct matrix inversion'
          endif
          call forwardmat(om(i), slo, r, hankel1, hankel2, uzerospecial)
          call modexp(i, spectra(1, i))
          do j=1,nslo
            green(j, i)=alpha(j)
          enddo
c 
        else
c 
c 7. discrete Fourier-Bessel transformation
c perform a Fourier Bessel transform
c ----------------------------------
          if (i.eq.1) then
            print *,' '
            print *,'do it by inverse Fourier Bessel transform'
            method='Fourier Bessel transform with '//kernel//' kernel'
          endif
          call backcoeff((verbose.and.(i.eq.1)), r, om(i), 
     &      spectra(1, i), chain, firstrec, hopnumberthis)
          call expmodel(om(i), r, slo, green(1, i), 
     &      hankel1, hankel2, uzerospecial, applywltaper)
          if (backtranscale) then
            if (i.eq.1) then
              call nullmodel(green)
            else
              rho=om(i)/rho
              rhoq=omq/rhoq
              call scalpark(nslo, rhoq, omq, green(1, i), slo,
     &          hopnumberthis,ntr)
            endif
          endif
c 
        endif
c 
c write phasor walkout to file
        call pwo_write(overwrite, verbose, method, r, ntr)
c 
c in any case make shure that verbose is switched on only for
c first loop cycle
c        verbose=.false.
      enddo
c 
c----------------------------------------------------------------------
c 
c write green code (easy to use)
c 
      print *,' '
      if (overwrite) then
        print *,'opening green file ',greensfile(1:index(greensfile,' ')),
     &    ' - overwrite mode'
        open(lu, file=greensfile, form='unformatted', err=98)
      else
        print *,'opening green file ',greensfile(1:index(greensfile,' '))
        open(lu, file=greensfile, status='new', form='unformatted', err=98)
      endif
      call tf_magic(cmagic, magic)
      write(lu, err=97) magic
      write(lu, err=97) nom, nslo
      write(lu, err=97) (om(i), i=1,nom), (slo(i), i=1,nslo)
      write(lu, err=97) ((green(j,i), i=1,nom), j=1,nslo)
      close(lu, err=96)
c 
      stop
   99 stop 'ERROR: reading command line argument'
   98 stop 'ERROR: opening green file'
   97 stop 'ERROR: writing green file'
   96 stop 'ERROR: closing green file'
      end
c
c======================================================================
c
c summary of general subroutines
c ==============================
c
c read sff seismogram traces
c --------------------------
c
c     subroutine readdata(filename, fdata, idata, spectra, r, maxr,
c    &     maxtr, maxsamp, ntr, nsamp, dt, tfirst)
c       
c stack all seismograms within stackdelta (option -B stackdelta)
c ---------------------------------------
c reads common blocks from greda.inc
c
c     subroutine stackthem(r, stackdelta, maxr, verbose)
c
c rescale Fourier coefficients (option -F)
c ----------------------------
c reads common blocks from greda.inc
c
c     subroutine dospecrescale(expon, r, om)
c
c rescale seismogram traces (option -r expon)
c -------------------------
c reads common blocks from greda.inc
c
c     subroutine dorescale(expon, r)
c
c apply time and offset domain tapering (many options)
c -------------------------------------
c
c     subroutine taper(maxsamp, maxtr, ntr, nsamp, tapfrac, offtapfrac,
c    &  maxr, spectra, r, offtaper, verbose, edgeset, edgefrac,
c    &  softcosine, gausstaper, gausstime)
c
c apply special offset domain taper (option -tap tapoffsets)
c ---------------------------------
c
c     subroutine specialtap(maxsamp, maxtr, ntr, nsamp, tapoffsets, maxr
c    &    spectra, r, verbose)
c
c calculate complex Fourier coefficients from waveform data
c ---------------------------------------------------------
c reads common blocks from greda.inc
c
c     subroutine calcspec(dt, tfirst, om, fmax, fmaxset)
c 
c write trace Fourier spectra (easy to use) (option -spo filename)
c ---------------------------------------­-
c reads common blocks from greda.inc
c 
c     subroutine Fourierwrite(filename, magic, cmagic, overwrite,
c    &  r, maxr, om)
c
c set slowness values for different expansion cases
c -------------------------------------------------
c fills the array slo with appropriate values
c
c     subroutine setslo(maxslo, nslo, smax, slo, 
c    &  hankel1, hankel2, uzerospecial)
c
c set coefficients for all slowness values to zero
c ------------------------------------------------
c reads common blocks from greda.inc
c
c     subroutine nullmodel(ogreen)
c
c expands the model, using alpha as expnsion coefficients and
c J_0, H^1_0, H^2_0 as a representer
c -----------------------------------------------------------
c reads common blocks from greda.inc
c
c     subroutine expmodel(omega, r, slo, ogreen, 
c    &  hankel1, hankel2, uzerospecial, applywltaper)
c
c numerically solve the system of linear equations for the gram matrix
c --------------------------------------------------------------------
c claculates the expansion coefficients alpha
c reads common blocks from greda.inc
c
c     subroutine modexp(iom, s)
c
c initialize wavelength specific taper parameters
c -----------------------------------------------
c reads common blocks from greda.inc
c
c     subroutine initwltaper(length,fraction)
c
c set wavelength specific taper to given wavelength
c -------------------------------------------------
c reads common blocks from greda.inc
c
c     subroutine setwltaper(omega,slo,r)
c
c----------------------------------------------------------------------
c 
c summary of subroutines specific to different approaches
c =======================================================
c
c fills expansion coefficients alpha with values appropriate to
c modified Fourier-Bessel transform
c -------------------------------------------------------------
c reads common blocks from greda.inc
c
c     subroutine backcoeff(verbose, r, omega, spect, chain, firstrec,
c    &                     numbers)
c
c calculate Gram matrix for linear inversion with exp-damping 
c -----------------------------------------------------------
c reads common blocks from greda.inc
c
c     subroutine gramex(rhoq, omq, r)
c
c scale greens matrix appropriate to exp-damping
c ----------------------------------------------
c
c     subroutine scalex(nslo, rhoq, ogreen, slo, ntr)
c
c calculate Greens matrix directly by Slant Stack
c -----------------------------------------------
c reads common blocks from greda.inc
c
c     subroutine planestack(omega, slo, r, green, iomega, applywltaper)
c
c fill Gram matrix for a direct inversion (that's a dirty method)
c ---------------------------------------
c reads common blocks from greda.inc
c
c     subroutine forwardmat(omega, slo, r, hankel1, hankel2, uzerospecial)
c
c calculate Gram matrix for linear inversion with K_0-damping
c -----------------------------------------------------------
c reads common blocks from greda.inc
c
c     subroutine gramkmet(rhoq, omq, r)
c
c scale Green matrix appropriate to K_0-damping
c ---------------------------------------------
c
c     subroutine scalkmet(nslo, rho, ogreen, slo, ntr)
c
c calculate Gram matrix for linear inversion with boxcar-damping
c --------------------------------------------------------------
c reads common blocks from greda.inc
c
c     subroutine gramdis(slo, om, r)
c
c function used by gramdis for numerical integration
c --------------------------------------------------
c
c     double precision function gramdisint(maxslo, nslo,
c    &  slo, rj, rk, om)
c
c calculate expansion coefficients alpha for linear inversion
c with Lorentz-damping
c -----------------------------------------------------------
c reads common blocks from greda.inc
c
c     subroutine parker(rho, r, s, chain, firstrec, numbers)
c
c scale Green matrix appropriate to Lorentz-damping
c -------------------------------------------------
c
c     subroutine scalpark(nslo, rhoq, omq, ogreen, slo, numbers, ntr)
c
c======================================================================
c
c some general subroutines
c
c----------------------------------------------------------------------
c
      subroutine readdata(filename, fdata, idata, spectra, r, maxr,
     &     maxtr, maxsamp, ntr, nsamp, dt, tfirst)
c 
c read sff seismic traces
c
      character filename*(*)
      integer maxtr, maxsamp, ntr, nsamp
      real fdata(maxsamp)
      integer idata(maxsamp)
      complex*16 spectra(maxtr, maxsamp)
      real r(maxtr), dt, tfirst, maxr
c 
      integer lu, ierr, i
      real version
      parameter(lu=20)
      character timestamp*20, code*10, type*20, cs*1, date*6, time*10
      character wid2line*132
      integer srctime(7), datatime(7), tdif(7), itdif(7)
      real sc1, sc2, sc3, c1, c2, c3, tanf, idt, sffu_seconds
      integer nstack, insamp, time_compare
      logical last
c 
c open sff-file
      print *,'open sff data ',filename(1:index(filename,' '))
      call sff_ROpenS(lu, filename, version, timestamp, code,
     &  type, cs, sc1, sc2, sc3, date, time, ierr)
      if (ierr.ne.0) stop 'ERROR: opening seismogram file'
      if (index(code, 'S').eq.0) stop 'ERROR: no SRCE line'
      if (cs.ne.'C') stop 'ERROR: source coordinates are not cartesian'
      call sffu_timesrce(date, time, srctime) 
      ntr=0
      maxr=0.
   1  continue
        ntr=ntr+1
        insamp=maxsamp
        call sff_RTraceI(lu, tanf, idt, wid2line, insamp, fdata, idata,
     &    code, last, cs, c1, c2, c3, nstack, ierr)
        if (ierr.ne.0) stop 'ERROR: reading trace'
        if (index(code, 'I').eq.0) stop 'ERROR: no INFO line'
        if (cs.ne.'C') stop 'ERROR: trace coordinates are not cartesian'
        call sffu_timewid2(wid2line, datatime)
        if (ntr.eq.1) then
          dt=idt
          nsamp=insamp
          call time_sub(datatime, srctime, tdif)
          tfirst=sffu_seconds(tdif)
        else
          call time_sub(datatime, srctime, itdif)
          if (nsamp.ne.insamp)
     &      print *,'NOTICE: your time series have inconsitent numbers ',
     &        'of samples'
          nsamp=max(nsamp,insamp)
          if ((dt.ne.idt).or.
     &        (time_compare(tdif, itdif).ne.0)) then
            print *,'ERROR: sampling interval or'
            stop 'ERROR: time of first sample differs from previous trace'
          endif
        endif
        r(ntr)=sqrt((sc1-c1)**2+(sc2-c2)**2+(sc3-c3)**2)
        maxr=max(maxr,r(ntr))
        do i=1,maxsamp
          spectra(ntr, i)=(0.,0.)
        enddo
        do i=1,insamp
          spectra(ntr, i)=cmplx(fdata(i))
        enddo
        if ((ntr.lt.maxtr).and.(.not.last)) goto 1
      if (.not.(last)) then
        print *,'NOTICE: will ignore traces after ',ntr
        close(lu)
      endif
      print *,'file read and closed'
      return
      end
c 
c----------------------------------------------------------------------
c
      subroutine stackthem(r, stackdelta, maxr, verbose)
c 
c stack all seismograms within stackdelta
c 
c get common block
      include 'greda_dim.inc'
      include 'greda.inc'
c 
      real r(maxtr), stackdelta, maxr
      logical verbose
c 
c something to work here
      logical obsolete(maxtr)
      integer i,j,k,n
      real refoff
c 
      print *,' '
      print *,'  stack traces within ',stackdelta,'m offset range'
      print *,'  (entered with ',ntr,' traces)'
c 
      do i=1,ntr
        obsolete(i)=.false.
      enddo
c 
      do i=1,ntr-1
        if (.not.(obsolete(i))) then
          n=1
          do j=i+1,ntr
            if (.not.(obsolete(j))) then
              refoff=r(i)/float(n)
              if (abs(r(j)-refoff).le.stackdelta) then
                n=n+1
                if (verbose) print *,'    stack ',j,' at ',r(j),' --> ',i,
     &            ' at ',r(i)
                obsolete(j)=.true.
                do k=1,nsamp
                  spectra(i,k)=spectra(i,k)+spectra(j,k)
                enddo
                r(i)=r(i)+r(j)
              endif
            endif
          enddo
          if (n.gt.1) then
            do k=1,nsamp
              spectra(i,k)=spectra(i,k)/float(n)
            enddo
            r(i)=r(i)/float(n)
            if (verbose) print *,'    ',n,' traces stacked to trace ',
     &        i,' at ',r(i)
          endif
        endif
      enddo
c 
      n=0
      do i=1,ntr
        if (.not.(obsolete(i))) then
          n=n+1
          if (n.ne.i) then
            do k=1,nsamp
              spectra(n,k)=spectra(i,k)
            enddo
            r(n)=r(i)
          endif
        endif
      enddo
c 
      ntr=n
      print *,'  ',ntr,' traces left after stacking'
c 
      maxr=r(1)
      do i=1,ntr
        maxr=max(maxr, r(i))
      enddo
c 
      return
      end
c 
c----------------------------------------------------------------------
c
      subroutine dospecrescale(expon, r, om)
c
c rescale traces Fourier coefficients
c
      include 'greda_dim.inc'
      include 'greda.inc'
c
      real expon, r(maxtr)
      real om(maxom)
c
      double precision fact
      integer i,j
c
      print *,' '
      print *,'rescale spectral coefficients to energy content of',
     &        ' (omega*r)^(-',expon,')'
c 
      do i=1,ntr
        do j=1,nsamp
          fact=sqrt((om(j)*r(i))**(-expon))
          spectra(i,j)=spectra(i,j)*fact/abs(spectra(i,j))
        enddo
      enddo
c 
      return
      end
c
c----------------------------------------------------------------------
c
      subroutine dorescale(expon, r)
c
c rescale traces
c
      include 'greda_dim.inc'
      include 'greda.inc'
c
      real expon, r(maxtr)
c
      double precision sum, fact
      integer i,j
c
      print *,' '
      print *,'rescale seismic traces to energy content of r^(-',expon,')'
c 
      do i=1,ntr
        sum=0.d0
        do j=1,nsamp
          sum=sum+real(spectra(i,j))*real(spectra(i,j))
        enddo
        fact=sqrt(r(i)**(-expon)/sum)
        do j=1,nsamp
          spectra(i,j)=spectra(i,j)*fact
        enddo
      enddo
c 
      return
      end
c
c----------------------------------------------------------------------
c 
      subroutine taper(maxsamp, maxtr, ntr, nsamp, tapfrac, offtapfrac,
     &  maxr, spectra, r, offtaper, verbose, edgeset, edgefrac,
     &  softcosine, gausstaper, gausstime)
c
c apply time and offset domain tapering
c
      integer maxsamp, maxtr, ntr, nsamp
      real tapfrac, offtapfrac, maxr, edgefrac
      double complex spectra(maxtr, maxsamp)
      real r(maxtr)
      logical offtaper, verbose, edgeset, softcosine, gausstaper
      logical gausstime
c 
      integer i, l, wil, wirb, wire
      real fac, tf_sincostap, rtap, pi, ltap
      double precision sigmaq
      parameter(pi=3.141592653589793)
c 
      print *,' '
      print *,'apply taper to input data'
c 
c first apply time domain taper
c 
      wil=int(nsamp*tapfrac/100.)+1
      wire=nsamp
      if (edgeset) wire=int(nsamp*edgefrac)
      wirb=wire-wil 
      if (gausstime) then
        tapfrac=max(tapfrac,1.e-10)
        sigmaq=-1.*(wire/2)**2/log(tapfrac*0.01)
        print *,'  using ',tapfrac,'% time domain gaussian taper'
        print *,'     (zero after sample ',wire,' with ',
     &    nsamp,' samples total)'
      else
        print *,'  using ',tapfrac,'% time domain cosine taper'
        print *,'    (full scale from sample ',
     &    wil,' to ',wirb
        print *,'     zero after sample ',wire,' with ',
     &    nsamp,' samples total)'
      endif
      do i=1,nsamp
        if (gausstime) then
          fac=exp(-1.*(i-wire/2.)**2/sigmaq)
          if (i.gt.wire) fac=0.
          if (verbose) print *,'  sample ',i,'   fac: ',fac
        else
          fac=tf_sincostap(i, 1, wil, wirb, wire)
        endif
        do l=1,ntr
          spectra(l,i)=fac*spectra(l,i)
        enddo
      enddo
c 
c apply offset domain taper
      if (offtaper) then
        if (gausstaper) then
          offtapfrac=max(offtapfrac,1.e-10)
          sigmaq=-1.*maxr*maxr/log(offtapfrac*0.01)
          print *,'  apply ',offtapfrac,
     &      '% offset domain gaussian taper'
          print *,'    from 0m to ',maxr,'m'
        else
          ltap=maxr*(1.-0.01*offtapfrac)
          rtap=maxr*(1.+(0.01*offtapfrac)**2)
          if (softcosine) then
            print *,'  apply ',offtapfrac,
     &        '% offset domain soft cosine taper'
          else
            print *,'  apply ',offtapfrac,
     &        '% offset domain hard cosine taper'
          endif
          print *,'    from ', ltap,'m to ',rtap,'m'
        endif
c 
        do i=1,ntr
          fac=1.
          if (gausstaper) then
            fac=exp(-1.*r(i)*r(i)/sigmaq)
          elseif (r(i).gt.ltap) then
            if (softcosine) then
c smooth taper
              fac=0.5*(1.+cos(pi*(r(i)-ltap)/(rtap-ltap)))
            else
c hard taper
              fac=cos(0.5*pi*(r(i)-ltap)/(rtap-ltap))
            endif
          endif
          if (verbose) then
            print *,'    at ',r(i),'m   fac: ',fac
          endif
          do l=1,nsamp
            spectra(i,l)=fac*spectra(i,l)
          enddo
        enddo
      else
        print *,'  no offset domain taper will be applied'
      endif
c 
      return
      end
c
c----------------------------------------------------------------------
c 
      subroutine specialtap(maxsamp, maxtr, ntr, nsamp, tapoffsets, 
     &    maxr, spectra, r, verbose)
c
c apply special offset domain taper
c
c 28/03/2006: order of array indices in spectra was wrong
c
      integer maxsamp, maxtr, ntr, nsamp
      real tapoffsets(4), maxr
      double complex spectra(maxtr, maxsamp)
      real r(maxtr)
      logical verbose
c 
      integer i, l
      real fac, pi
      parameter(pi=3.141592653589793)
c 
      print *,' '
      print *,'apply special offset taper to input data'
      print *,'  min=',tapoffsets(1),', left=',tapoffsets(2),
     & ' right=',tapoffsets(3),', max=',tapoffsets(4)
c 
c apply offset domain taper
c 
      do i=1,ntr
        fac=1.
        if (r(i).lt.tapoffsets(1)) then
          fac=0.
        elseif (r(i).gt.tapoffsets(4)) then
          fac=0.
        elseif (r(i).lt.tapoffsets(2)) then
          fac=sin(0.5*pi*(r(i)-tapoffsets(1))/
     &      (tapoffsets(2)-tapoffsets(1)))
        elseif (r(i).gt.tapoffsets(3)) then
          fac=cos(0.5*pi*(r(i)-tapoffsets(3))/
     &      (tapoffsets(4)-tapoffsets(3)))
        else
          fac=1.
        endif
        if (verbose) then
          print *,'    at ',r(i),'m   fac: ',fac
        endif
        do l=1,nsamp
          spectra(i,l)=fac*spectra(i,l)
        enddo
      enddo
c 
      return
      end
c
c----------------------------------------------------------------------
c
      subroutine calcspec(dt, tfirst, om, fmax, fmaxset)
c 
c calculate complex spectra of time series data
c
c get common block
      include 'greda_dim.inc'
      include 'greda.inc'
c
      real dt, tfirst, om(maxom), fmax
      logical fmaxset
c 
      real scal, df
      integer i, j, pow, newnsamp
      real pi2
      parameter(pi2=2.*3.141592653589793)
c 
      print *,' '
      print *,'transform dataset to frequency domain'
c now get next integer power of two
      pow=0
    1 continue
        pow=pow+1
        newnsamp=2**pow
        if (newnsamp.lt.nsamp) goto 1
      if (newnsamp.gt.maxsamp)
     &  stop 'ERROR: can not fit integer power of two into samples dimension'
c 
c get correct scaling factor to manipulate FORK
      scal=dt*sqrt(float(newnsamp))
c calculate other values
      nom=newnsamp/2+1
      df=1/(newnsamp*dt)